Date:         Tue, 17 Mar 1998 09:45:51 -0500
Reply-To:     msz03@HEALTH.STATE.NY.US
Sender:       "SAS(r) Discussion" <SAS-L@UGA.CC.UGA.EDU>
From:         Mike Zdeb <msz03@HEALTH.STATE.NY.US>
Subject:      Fw: GMAP & thickening borders.
Content-Type: text/plain; charset="iso-8859-1"

This might be of general interset to those mapping with SAS/GRAPH.
 
-----Original Message-----
From: Mike Zdeb <msz03@albnydh2.health.state.ny.us>
To: SCOTT SCHEFFLER <OKPRO.SSCHEFFL@SDPS.ORG>
Date: Tuesday, March 17, 1998 9:22 AM
Subject: Re: GMAP & thickening borders.
 
 
>Hi.  I've seen a couple of answers posted.  The real simple way to do this
>(though it will thicken ALL lines in your output) is via the GOPTIONS
>statement...
>
>
>goptions lfactor=n;
>
>The defult for n is 1.  You can go up to 9999, but that's a tad thick.
>
>
>If you still just want JUST the counties with thicker borders, the solution
>is (gulp) annotate.  There was code posted in SAS Communications to turn a
>county boundary file into an annotate data set....(variable SIZE controls
>the line thickness)...(the county boundary file here is maps.nyscou96)...
>
>data coutline;
>retain from -1 xsave ysave;
>drop   xsave ysave;
>length function color $8;
>retain xsys ysys '2' color 'black' size 12 when 'a';
>set maps.nyscou96;
>by county segment;
>if first.segment then do;
>   function = 'move';
>   xsave = x;
>   ysave = y;
>   output;
>end;
>else do;
>   function = 'draw';
>   output;
>   if last.segment then do;
>      x = xsave;
>      y = ysave;
>      output;
>      end;
>   end;
>run;
>
>Once you have this annotate data set, combine it with the county boundaries
>(the map dataset) and project them as one dataset....
>
>data both;
>set coutline
>maps.nyscou96;
>run;
>
>proc gproject data=both out=proj asis;
>id county;
>run;
>
>Then separate them again into an annotate dataset and the projected mapping
>dataset...
>
>data anno map;
>set proj;
>if from eq . then output map;
>else              output anno;
>run;
>
>Now you can do the map and layer on the thick border with annotate=anno as
>an option in GMAP.
>
>proc gmap data=<whatever> map=map;
>id county;
>choro var/annotate=anno;
>quit;
>
>
>
>-----Original Message-----
>From: SCOTT SCHEFFLER <OKPRO.SSCHEFFL@SDPS.ORG>
>To: SAS-L@UGA.CC.UGA.EDU <SAS-L@UGA.CC.UGA.EDU>
>Date: Monday, March 16, 1998 5:41 PM
>Subject: GMAP & thickening borders.
>
>
>>I'm producing a state map that has an
>>immunization rate for each county.  The program
>>runs fine; however, I would like to thicken the
>>line used for the county borders.  I haven't
>>been able to find anything in the manuals like
>>the WIDTH option for the SYMBOL statement.
>>
>>I'm using SAS v6.11 (on a PC) and the GMAP
>>procedure with a CHORO statement.  I don't have
>>the GIS package.  Perhaps somebody knows
>>the trick.
>>
>>TIA,
>>Scott
>