Date:         Tue, 4 Nov 2008 05:43:27 -0800
Reply-To:     "Richard A. DeVenezia" <rdevenezia@WILDBLUE.NET>
Sender:       "SAS(r) Discussion" <SAS-L@LISTSERV.UGA.EDU>
From:         "Richard A. DeVenezia" <rdevenezia@WILDBLUE.NET>
Organization: http://groups.google.com
Subject:      Re: regarding proc report
Comments: To: sas-l@uga.edu
Content-Type: text/plain; charset=ISO-8859-1

such wrote:
> Hello,
>
> I am a new member of this group.
>
> May be the question i am asking is a very easy but unable to solve the
> problem myself.
>
> I am producing listings for a project using Proc Report, earlier used
> to print it using data null. I want to have "Continued" at the end of
> each page until that listing is over. Eg: a listing continues to 3
> pages, so on pages 1 and 2 at the end of table "Continued" should
> appear an dnot on Page 3.

Recollection is that the 'continued' situation is a continuing saga.
Version 9.2 or >9.2 may have new Proc options or option values to
automatically do what you want .  It might be an ODS setting affecting
any procedure that generates multi-page tabular output.

This sample code is a hack for a simple PDF report and has to be
tweaked according to the fonts and font sizes used in the report.

--------------------------
  %let ROWS_PER_PAGE = 35;

  data foo;
    do i = 1 to 150;
      y1 = ranuni(1234);
      y2 = ranuni(1234);
      output;
    end;
  run;

  data reportData;
    set foo end=end;

    retain pageNumber 0;

    if mod(_N_-1,&ROWS_PER_PAGE) = 0 then
      pageNumber + 1;

    if end then
      call symputx('LAST_PAGE_NUMBER',pageNumber);
  run;

  options
    PDFPAGEVIEW = FITPAGE
  ;

  ods listing close;
  ods pdf
    file = "%sysfunc(PATHNAME(WORK))/report.pdf)"
  ;

  %put %sysfunc(getoption(PS));

  proc report nowindows data=reportData;
    define pageNumber / order noprint;
    define i / display;

    compute after pageNumber / style=[just=right];
      if pageNumber < &LAST_PAGE_NUMBER. then
        text = 'Continued...';
      else
        text = '';

      line text $200.;
    endcomp;
  run;

  ods pdf close;

  options
    PDFPAGEVIEW = DEFAULT
  ;
--------------------------

There are also numerous conference papers written by various authors
regarding 'continued'.  You can search those up.

--
Richard A. DeVenezia
http://www.devenezia.com