|
Pete Lund wrote:
> Hi all-
> I'm creating a plot in a PDF document. I have ROTATE=LANDSCAPE set
> in a goptions statement which works fine, with one problem. The plot
> comes out in landscape with the top of the plot (titles, etc.) on the
> right side of the page. I want the top to be on the left side of the
> page.
>
> The plot is interspersed with tabular data, in portrait
> orientation, and the current orientation of the plot puts the bottom
> on the binding edge. Is there a way to specify which direction the
> plot should rotate?
>
> Thanks-
> Pete
I've heard the term "SEASCAPE" used to describe a flipped landscape.
Here is one way, using GREPLAY, to render your graphs in seascape. A
template is used, the coordinates of LL, LR, UL, UR are reversed from their
normal expectations. Only one problem... hardware fonts rendered by replay
through ODS don't... Might be a bug or a 'feature'. Use a SAS/Graph font
such as ftext=SWISS instead of ftext='Arial'. Unfortunately, SWISS is lame
in comparison in 'Arial'.
ods listing close;
ods pdf file="%sysfunc(pathname(WORK))\report.pdf";
proc print data=sashelp.class;
goptions reset=all;
goptions rotate=landscape display;
goptions display ftext='Arial';
proc gchart data=sashelp.class gout=work.chart;
vbar age / name="ChartOne"; * Arial;
run;
quit;
goptions ftext=SWISS;
proc gchart data=sashelp.class gout=work.chart;
vbar age / name="ChartTwo"; * SWISS;
run;
quit;
proc greplay igout=work.chart tc=work.templat nofs;
tdef seascape des = "Seascape orientation"
1 /
llx = 100
lly = 100
lrx = 000
lry = 100
ulx = 100
uly = 000
urx = 000
ury = 000
;
template Seascape;
treplay 1:ChartOne; * NOT Arial, sigh;
treplay 1:ChartTwo; * SWISS;
run;
quit;
ods pdf close;
--
Richard A. DeVenezia
http://www.devenezia.com/downloads/sas/samples
| 
