Date:         Mon, 2 Feb 2004 18:16:22 -0500
Reply-To:     "Michael S. Zdeb" <msz03@HEALTH.STATE.NY.US>
Sender:       "SAS(r) Discussion" <SAS-L@LISTSERV.UGA.EDU>
From:         "Michael S. Zdeb" <msz03@HEALTH.STATE.NY.US>
Subject:      Re: Gplot Legend too large
Content-type: text/plain; charset=us-ascii

Hmmmm...GPLOT with 30 symbols - 30 lines on one plot?  Anyway...have you
tried tweaking the layout and location of the legend...

data test;
do xyz = 1 to 30;
do x   = 1 to 10;
   y = 10 * ranuni(1234);
   output;
end;
end;
run;

%macro symbols;
%do i=1 %to 10;
symbol&i i=j l=&i color=blue;
%end;
%do i=11 %to 20;
symbol&i i=j l=&i color=red;
%end;
%do i=21 %to 30;
symbol&i i=j l=&i color=green;
%end;
%mend;

goptions reset=all device=gif xpixels=800 ypixels=600 ftext='Tahoma' htext=
2 gunit=pct gsfname=gif_out;

%symbols;

legend1 across=1 frame origin=(90,10)pct mode=share label=(position=top);

title1 h=4 'TOO MANY LINES ON ONE PAGE';
*** use a rotated title to make room on the right;
title2 a=-90 h=15pct ' ';

filename gif_out 'z:\toomanylines.gif';

proc gplot data=test;
plot y*x=xyz / legend=legend1;
run;
quit;


Mike Zdeb
U@Albany School of Public Health
1 University Drive
Rensselaer, NY   12144-3456
(P)518-402-6479
(F)630-604-1475


|---------+---------------------------->
|         |           A Ludtke         |
|         |           <amy.ludtke@COMCA|
|         |           ST.NET>          |
|         |           Sent by: "SAS(r) |
|         |           Discussion"      |
|         |           <SAS-L@LISTSERV.U|
|         |           GA.EDU>          |
|         |                            |
|         |                            |
|         |           02/02/2004 05:17 |
|         |           PM               |
|         |           Please respond to|
|         |           A Ludtke         |
|         |                            |
|---------+---------------------------->
  >----------------------------------------------------------------------------------------------------------------------|
  |                                                                                                                      |
  |       To:       SAS-L@LISTSERV.UGA.EDU                                                                               |
  |       cc:                                                                                                            |
  |       Subject:  Gplot Legend too large                                                                               |
  >----------------------------------------------------------------------------------------------------------------------|




I'm creating multiple plots using Proc Gplot with the ODS driver to output
GIFs and HTMLs.  My legend is very large (>30 symbols at times) and is
using
up too much of my graphics area, and reducing the plot's size.  Yet,
obviously I need the plot viewable as well as the legend.  I've tried
expanding my y-pixels to push the legend off to a 2nd page, but that was
disastrous, making all of my fonts huge and distorted.  I tried putting in
a
negative y-origin, and that just made the legend disappear.  Any
 suggestions?