Date:         Mon, 14 Jan 2002 13:53:36 -0800
Reply-To:     "Huang, Ya" <ya.huang@PFIZER.COM>
Sender:       "SAS(r) Discussion" <SAS-L@LISTSERV.UGA.EDU>
From:         "Huang, Ya" <ya.huang@PFIZER.COM>
Subject:      Re: ods graph pdf question
Comments: To: Crystal Vierhout <vierhout@unity.ncsu.edu>
Content-Type: text/plain; charset="iso-8859-1"

Hi Crystal,

I am not sure how it can be done with ODS. But you can
try use SAS native pdf drive and proc greplay. The following
test code will generate a pdf file with two plots (box plot,
gplot) on the left and some text one right. I am not familiar
with proc capability, but you can do the same thing as gplot
and boxplot, just make sure to put gout=work.gcat option,
then you have to create your own template for greplay, since
SAS dose not provide a build-in template for that kind of layout.

data x1;
do x=1 to 10;
y=ranuni(0);
output;
end;

data x2;
do x=0 to 6.5 by 0.1;
y=sin(x);
output;
end;

proc boxplot data=x1 gout=work.gcat;
plot y*x;
run;

proc gplot data=x2 gout=work.gcat;
plot y*x;
run;
quit;

** this part to generate a text file, you can;
** also use any exsiting text file;
filename ftext temp;
data _null_;
file ftext;
put 'This is the description for proc bocplot';
put 'This is the description for proc capability';
put 'This is the description for proc gplot';
run;

goptions htext=5pt;
proc gprint fileref=ftext gout=work.gcat;
run;

filename pdf 'c:\temp\threegraph.pdf';
goptions gsfname=pdf device=pdf gsfmode=replace;

proc greplay igout=work.gcat
tc=sashelp.templt nofs;
template=l2r1;
treplay 1:boxplot
        2:gplot
        3:gprint;

quit;

You may need some adjustment to goptions to make it
nicer looking.

HTH

Ya Huang

-----Original Message-----
From: Crystal Vierhout [mailto:vierhout@unity.ncsu.edu]
Sent: Monday, January 14, 2002 1:23 PM
To: SAS-L@LISTSERV.UGA.EDU
Subject: ods graph pdf question


Nothing like trying to hit everything in one question.


I am trying to get a one page pdf file with three graphs on the left side on
a single page.  On the right side of the page lines for the end user to
write about the graphs.  My three graphs are

Proc boxplot
Proc capability
proc plot

I'm getting confused on how to do this.  I have found a sas-L email from
Bill Droogendyk on October 26 but am unable to get it to work.  I'm sure he
has it correct but maybe this is not the time to use this design.  Anyone
could help I would be greatly appreciated.



Crystal Vierhout
Dairy Records Management Systems