Date:         Wed, 23 May 2001 13:11:29 -0700
Reply-To:     "Smith, Curtis, Mr, DCAA" <Curtis.Smith@DCAA.MIL>
Sender:       "SAS(r) Discussion" <SAS-L@LISTSERV.UGA.EDU>
From:         "Smith, Curtis, Mr, DCAA" <Curtis.Smith@DCAA.MIL>
Subject:      FW: [SAS-L] ODS Styles
Comments: cc: "Matt.Flynn@thehartford.com" <Matt.Flynn@thehartford.com>
Content-Type: text/plain; charset="iso-8859-1"

Boy, not only did Matt point me to where within SAS you can see the style=
options for the ODS HTML statement; not only did he point me to a great SAS
technical report; but he also sent me some awesome code for generating HTML
samples from each of the available styles (see below).

Thanks, Matt!

-----Original Message-----
From: Flynn, Matt J (PLIC, RESEARCH) [mailto:Matt.Flynn@thehartford.com]

Sent: Wednesday, May 23, 2001 12:48 PM
To: 'Smith, Curtis, Mr, DCAA'
Subject: RE: [SAS-L] ODS Styles


Curtis:

See:

http://www.sas.com/service/techtips/quicktips/stods.html

or in display manager
  F10, Tools, Options, Preferences, Results, Style


 /* styles.sas */
* example to illustrate the use of available standard ODS html styles;


data slist;
        input style $1-15;
cards;
BarrettsBlue
Beige
Brick
Brown
D3D
Default
FancyPrinter
Minimal
NofontDefault
Printer
Rtf
SansPrinter
SasdocPrinter
SASweb
SerifPrinter
Statdoc
Theme
;
run;

***------------------------------------------------------------------;
data links;
        set slist;
   link="<A HREF='style_"|| trim(style) ||".htm'>"||trim(style)||"</A>";
;
proc print;
ods noproctitle;
ods html file='~/examples/odsstyles/stylelist.htm';
proc print data=links noobs;
        var link;
        title 'ODS Styles';
run;
ods html close;
***----------------------------------------------------------------;
/* grab list of styles into macro var */
proc sql noprint;
        select style
            into : slist
                 separated by ' '
                                from slist;
quit;
%put slist=&slist;

/* create some dummy data */
data one;
        do x = 1 to 5;
                y=rannor(12345);
                output;
        end;
run;

/* cycle through list - output in different styles */
%macro doit;
%do i = 1 %to &sqlobs;
        %let st=%qscan(&slist,&i,' ');
        %put i=&i st=&st;

ods html file="~/examples/odsstyles/style_&st..htm" style=&st;

proc print data=one;
        title "style= &st";
        title2 "<A HREF='stylelist.htm'>Back to stylelist</A>";
run;;
proc means data=one n nmiss min q1 median mean stddev q3 max;
        var x y;
run;

ods html close;
%end;
%mend;
%doit;

-----Original Message-----
From: Smith, Curtis, Mr, DCAA [mailto:Curtis.Smith@DCAA.MIL]
Sent: Wednesday, May 23, 2001 3:27 PM
To: SAS-L@LISTSERV.UGA.EDU
Subject: [SAS-L] ODS Styles


Anyone know where I can see a complete listing of the available ODS Style=
options?

> *-------------------------------------------*
> | Curtis A. Smith                           |
> | Defense Contract Audit Agency             |
> | Boeing Huntington Beach Resident Office   |
> | 5301 Bolsa Avenue, M/C H014-A405          |
> | Huntington Beach, CA 92647-2099           |
> | Voice:   714-896-3311 x67492              |
> | FAX:     714-896-6915                     |
> | E-Mail:  curtis.smith@dcaa.mil            |
> *-------------------------------------------*
>
>